***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jan 30, 2026                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the data sheet for specification limits.                             *
***********************************************************************
*$
.subckt   PJT7801     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs     s1    s2    205u  TC=3m
Rg     g1    g2    248.70
M1     d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS  PMOS (KP=8.450  VTO=-1.010  LEVEL=3  VMAX=1e5  ETA=0  NFS=2.600e11  GAMMA=5.000e-1 )
Rd     d1    d2    2.015e-1 TC=3.300e-3,4.900e-6
Dbd    d2    s2    Dbt
.MODEL       Dbt   D(IS=4.100e-11   N=1.180  RS=4.000e-5  EG=9.800e-1  TT=30n IKF=8.075e-2 TIKF=1.00e-2
+                    BV=22  TBV1=6.905e-4  TBV2=1.005e-9   CJO=3.249e-11   M=3.251e-1   VJ=4.038e-1)
Dbody  21    s2    DBODY
.MODEL DBODY D (IS=5.100e-12   N=1.180  RS=4.000e-5  EG=9.800e-1  TT=30n IKF=8.075e-2 TIKF=1.00e-2)
Rdiode d1    21    2.030e-1   TC=-2.000e-3,1.000e-6
.MODEL sw    PMOS(VTO=0  KP=10   LEVEL=1)
Maux   g2    c     a     a    sw
Maux2  b     d     g2    g2   sw
Eaux   c     a     d2    g2   1
Eaux2  d     g2    d2    g2   -1
Cox    b     d2    1.011e-10
.MODEL DGD   D (CJO=1.011e-10 M=7.960e-1  VJ=4.9255e-1)
Rpar   b     d2    1Meg
Dgd    d2    a     DGD
Rpar2  d2    a     10Meg
Cgs    g2    s2    1.549e-10
.ENDS PJT7801
*$
